Datenbank mit dem Recordset-Objekt abfragen

Das ADO-Recordset-Objekt stellt die Ergebnismenge einer Abfrage dar. Sie können es benutzen, um Daten aus einer Datenbank anzuzeigen.

Beispielcode

Sie können diese Routine ausprobieren, indem Sie eine Befehlsschaltfläche namens cmdQuery in einer Maske platzieren und die Routine in ihr Klick-Ereignis einfügen. Führen Sie das Programm aus und klicken Sie auf die Schaltfläche, um eine Verbindung herzustellen, eine Meldung im Fenster "Datenbankservermeldungen" anzuzeigen, eine Abfrage auszuführen und die ersten Zeilen in Fenstern anzuzeigen. Danach trennen Sie die Verbindung.

Private Sub cmdQuery_Click( _
        ByVal eventSender As System.Object, _
        ByVal eventArgs As System.EventArgs) _
        Handles cmdQuery.Click

    ' Declare variables
    Dim i As Integer
    Dim myConn As New ADODB.Connection
    Dim myCommand As New ADODB.Command
    Dim myRS As New ADODB.Recordset
    
    On Error GoTo ErrorHandler
    
    ' Establish the connection
    myConn.Provider = "SAOLEDB"
    myConn.ConnectionString = _
        "Data Source=SQL Anywhere 11 Demo"
    myConn.CursorLocation = _
        ADODB.CursorLocationEnum.adUseServer
    myConn.Mode = _
        ADODB.ConnectModeEnum.adModeReadWrite
    myConn.IsolationLevel = _
        ADODB.IsolationLevelEnum.adXactCursorStability
    myConn.Open()
    
    'Execute a query
    myRS = New ADODB.Recordset
    myRS.CacheSize = 50
    myRS.let_Source("SELECT * FROM Customers")
    myRS.let_ActiveConnection(myConn)
    myRS.CursorType = ADODB.CursorTypeEnum.adOpenKeyset
    myRS.LockType = ADODB.LockTypeEnum.adLockOptimistic
    myRS.Open()
    
    'Scroll through the first few results
    myRS.MoveFirst()
    For i = 1 To 5
        MsgBox(myRS.Fields("CompanyName").Value, 
            MsgBoxStyle.Information)
        myRS.MoveNext()
    Next 
    
    myRS.Close()
    myConn.Close()
    Exit Sub
    
ErrorHandler: 
    MsgBox(ErrorToString(Err.Number))
    Exit Sub
End Sub

Hinweise

Das Recordset-Objekt in diesem Beispiel enthält die Ergebnisse aus einer Abfrage der Tabelle Customers. Die For-Schleife durchläuft die ersten Zeilen und zeigt für jede Zeile den Wert CompanyName an.

Hierbei handelt es sich um ein einfaches Beispiel für die Verwendung eines Cursors aus ADO.

Weiterführende Beispiele für die Verwendung eines Cursors aus ADO finden Sie unter Mit dem Recordset-Objekt arbeiten.

Kommentieren Sie diese Seite in DocCommentXchange.
Senden Sie uns Feedback über diese Seite via E-Mail.